Vala Tutorial

Contents

Vala Tutorial

Introduction

Disclaimer: Vala is an ongoing project, and its features may change. I will try to keep this tutorial as up to date as I can, but I'm not perfect. Also, I can't promise that the techniques which I suggest are necessarily the best in practice, but again I will try to keep up with that sort of thing.

What is Vala?

Vala is a new programming language that allows modern programming techniques to be used to write applications that run on the GNOME runtime libraries. In particular, glib and gobject. This platform has long provided a very complete programming environment, with such features as a dynamic type system and assisted memory management. Before Vala, the only ways to program for the platform were with the machine native C API, which exposes a lot of often unwanted detail. With a high level language that has an attendant virtual machine, such as Python or the Mono language. Or alternatively, with C++ through a wrapper library.

Vala is different from all these other techniques, as it outputs C code which can be compiled to run with no extra library support beyond the GNOME platform. This has several consequences, but most importantly:

Programs written in Vala should have broadly similar performance to those written directly in C, whilst being easier and faster to write and maintain.
A Vala application can do nothing that a C equivalent cannot. Whilst Vala introduces a lot of language features that are not available in C, these are all mapped to C constructs, although they are often ones that are difficult or too time consuming to write directly.

As such, whilst Vala is a modern language with all of the features you would expect, it gains its power from an existing platform, and must in some ways comply with the rules set down by it.

Who is this tutorial for?

This tutorial will not go into depth about basic programming practices. It will only briefly explain the principles of object-oriented programming, instead focusing on how Vala applies the concepts. As such it will be helpful if you have experience of a variety of programming languages already, although in-depth knowledge of any particular one is not required.

Vala shares a lot of syntax with C#, but I will try to avoid describing features in terms of their similarity or differences with either C# or Java, with the aim of making the tutorial more accessible.

What will be useful is a reasonable understanding of C. Whilst this isn't needed for understanding Vala per se, it is important to realise that Vala programs are executed as C, and will often interact with C libraries. Knowledge of C will certainly make a deeper understanding of Vala far easier to come by.

Conventions

Code will be in monospaced text, commands will all be prefaced with a $ prompt. Other than that, everything should be obvious. I tend to code very explicitly, including some information that is actually implied. I will try to explain where some things can be omitted, but that doesn't mean that I encourage you do to this.

At some point I will add in references to the Vala documentation, but that isn't really possible yet.

A First Program

Sadly predictable, but still:

using GLib;

public class Test.HelloObject : GLib.Object {

    public static int main(string[] args) {

        stdout.printf("Hello, World\n");

        return 0;
    }
}

Of course, that is Vala's Hello World program. I expect you can recognise some parts of it well enough, but just to be thorough I shall go through it step by step.

using GLib;

A using line informs the compiler that this file is going to be referring to things in the namespace given, and therefore allows them to be used without giving their fully qualified name. The GLib namespace is imported by default, so this line is actually not necessary for GLib.

public class Test.HelloObject : GLib.Object {

This line identifies the beginning of a class definition. Classes in Vala are very similar in concept to other languages. A class is basically a type of object, of which instances can be created, all having the same properties. The implementation of classed types is taken care of by the gobject library, but details of this are not important for general usage.

What is important to note is that this class is specifically described as being a subclass of GLib.Object. This is because Vala allows other types of class, but in most cases, this is the sort that you want. In fact, some language features of Vala are only allowed if your class is descended from GLib's Object.

Other parts of this line show namespacing and fully qualified names, although these will be explained later.

public static int main(string[] args) {

This is the start of a method definition. A method is a function related to a type of object that can be executed on an object of that type. The static method means that the method can be called without possessing a particular instance of the type. The fact that this method is called main and has the signature it does means that Vala will recognise it as the entry point for the program.

The main method doesn't have to be defined inside a class. However, if it is defined inside a class it must be static. It doesn't matter if it's public or private. The return type may be either int or void. With a void return type the program will implicitly terminate with exit code 0. The string array argument which holds the command line parameters is optional.

stdout.printf("Hello, World\n");

stdout is an object in the GLib namespace that Vala ensures you have access to whenever required. This line instructs Vala to execute the method called printf of the stdout object, with the hello string as an argument. In Vala, this is always the syntax you use to execute a method on an object, or to access an object's data. \n is the escape sequence for a new line.

return 0;

return is to return a value to the caller and terminate the execution of the main method which also terminates the execution of the program. The returned value of the main method is then taken as the return value of the program.

The last lines simply end the definitions of the method and class.

Compile and Run

Assuming you have Vala installed, then all it takes to compile and execute this program is:

$ valac hello.vala
$ ./hello

valac is the Vala compiler, which will compile your Vala code into a binary. The resulting binary will have the same name as the source file and can then be directly executed on the machine. You can probably guess the output.

If you want the binary to have a different name or if you have passed multiple source files to the compiler you can specify the binary name explicitly with the -o switch:

$ valac source1.vala source2.vala -o myprogram
$ ./myprogram

If you give valac the -C switch, it won't compile your program into a binary file. Instead it will output the intermediate C code for each of your Vala source files into a corresponding C source file, in this case hello.c. If you look at the content of these files you can see that programming a class in Vala is equivalent to the same task in C, but a whole lot more succinct. You will also notice that this class is defined dynamically in the running system. This is a good example of the power of the GNOME platform, but as I've said before, you do not need to know much about this to use Vala.

If you want to have a C header file for your project you can use the -H switch:

$ valac hello.vala -C -H hello.h

Basics

Source Files and Compilation

Vala code is written in files with .vala extensions. Vala does not enforce as much structure as a language like Java - there are not concepts of packages or class files in the same way. Instead structure is defined by text inside each file, describing the logical location of the code with constructs such as namespaces. When you want to compile Vala code, you give the compiler a list of the files required, and Vala will work out how they fit together.

The upshot of all this is that you can put as many classes or functions into a file as you want, even combining parts of different namespaces in together. This is not a good idea.

There are certain conventions you probably want to follow. A good example of how to structure a project in Vala is the Vala project itself.

All source files for the same package are supplied as command line parameters to the Vala compiler valac, along with compiler flags. This works similarly to how Java source code is compiled. For example:

$ valac compiler.vala --pkg libvala

will produce a binary with the name compiler that links with the package libvala. In fact, this is how the valac compiler is produced!

Syntax Overview

Vala's syntax is an amalgam heavily based on C#'s. As a result, most of this will be familiar to programmers who know any C-like language, and in light of this I have kept things brief.

Scope is defined using braces. An object or reference is only valid between { and }. These are also the delimiters used to define classes, functions, code blocks etc, so they automatically have their own scope. Vala is not strict about where variables are declared.

An identifier is defined by its type and a name, e.g. int c meaning an integer called c. In the case of value types this also creates an object of the given type. For reference types these just define a new reference that doesn't initially point to anything.

For identifier names the same rules apply as for C identifiers: the first character must be one of [a-z], [A-Z] or an underscore, subsequent characters may additionally be digits [0-9]. Other Unicode characters are not allowed. It is possible to use a reserved keyword as identifier name by prefixing it with the @ character. This character is not part of the name. For example, you can name a function foreach by writing @foreach, even though this is a reserved Vala keyword.

Reference types are instantiated using the new operator and the name of a construction method, which is usually just the name of the type, e.g. Object o = new Object() creates a new Object and makes o a reference to it.

Comments

Vala allows comments in code in different ways.

// Comment continues until end of line

/* Comment lasts between delimiters */

/** Documentation comment */

These are handled in the same way as in most other languages and so need little explanation. Documentation comments are actually not special to Vala, but a tool like Valadoc will recognise them.

Data Types

Broadly speaking there are two types of data in Vala: reference types and value types. These names describe how instances of the types are passed around the system - a value type is copied whenever it is assigned to a new identifier, a reference type is not copied, instead the new identifier is simply a new reference to the same object.

A constant is defined by putting const before the type. However, local constants are not yet supported, which means you can't define a constant inside a function, only outside. The naming convention for constants is ALL_UPPER_CASE.

Value Types

Vala supports a set of the simple types as most other languages do.

Byte, char, uchar; their names are char for historical reasons.
Character, unichar
Integer, int, uint
Long Integer, long, ulong
Short Integer, short, ushort
Guaranteed-size Integer, int8, int16, int32, int64 as well as their unsigned siblings uint8, uint16, uint32, uint64. The numbers indicate the lengths in bits.
Float number, float, double
Boolean, bool; possible values are true and false
Compound, struct
Enumeration enum; represented by integer values, not as classes like Java's enums

Here are some examples.

/* atomic types */
unichar c = 'u';
float percentile = 0.75f;
const double MU_BOHR = 927.400915E-26;
bool the_box_has_crashed = false;

/* defining a struct */
struct Vector {
    public double x;
    public double y;
    public double z;
}

/* defining an enum */
enum WindowType {
    TOPLEVEL,
    POPUP
}

Most of these types may have different sizes on different platforms, except for the guaranteed-size integer types. With sizeof() you can get the size of a type in bytes:

ulong nbytes = sizeof(int32);    // nbytes will be 4 (= 32 bits)

You can determine the minimum and maximum values of a numerical type with .MIN and .MAX, e.g. int.MIN and int.MAX.

Strings

The data type for strings is string. Vala strings are UTF-8 encoded and immutable.

string text = "A string literal";

Vala offers a feature called verbatim strings. These are strings in which escape sequences (such as \n) won't get interpreted, line breaks will be preserved and quotation marks don't have to be masked. They get enclosed with triple double quotation marks. Possible indentations after a line break are part of the string as well.

string verbatim = """This is a so-called "verbatim string".
Verbatim strings don't process escape sequences, such as \n, \t, \\, etc.
They may contain quotes and may span multiple lines.""";

Strings prefixed with '@' are string templates. They can evaluate embedded variables and expressions prefixed with '$':

int a = 6, b = 7;
string s = @"$a * $b = $(a * b)";

The equality operator == compares the content of two strings, contrary to Java's behaviour which in this case would check for referential equality.

Arrays

An array is created by giving a type name followed by [] and assigned using the new operator e.g. int[] a = new int[10] to create an array of integers. The length of such an array can be obtained by the length member variable e.g. int count = a.length;. Note that if you write Object[] a = new Object[10] no Objects will be created, just the array to store them in.

int[] a = new int[10];
int[] b = { 2, 4, 6, 8 };

Multi-dimensional arrays are defined with [,] or [,,] etc.

int[,] c = new int[3,4];
int[,] d = {{2, 4, 6, 8},
            {3, 5, 7, 9},
            {1, 3, 5, 7}};
d[2,3] = 42;

This sort of array is represented by a single contiguous memory block. Jagged multi-dimensional arrays ("arrays of arrays"), where each row may have a different length, are not yet supported.

Vala does not do any bounds checking for array access at runtime. If you need more safety you should use a more sophisticated data structure like an ArrayList.

Referenced Types

The referenced types are all types declared as a class, regardless of whether they are descended from GLib's Object. Vala will ensure that when you pass an object by reference the system will keep track of the number of references currently alive in order to manage the memory for you. The value of a reference that does not point anywhere is null. More on referenced types in the section about object oriented programming.

/* defining a class */
public class Track : GLib.Object {
    public double mass;
    public double name { get; set; }
    private bool terminated = false;
    public void terminate() {
        termintated = true;
    }
}

Static Type Casting

In Vala, you can cast a variable from one type to another. For a static type cast, a variable is casted by the desired type name with parenthesis. A static cast doesn't impose any runtime type safety checking. It works for all Vala types. For example,

int i = 10;
float j = (float) i;

Vala supports another casting mechanism called dynamic cast which performs runtime type checking and is described in the section about object oriented programming.

Type Inference

Vala has a mechanism called type inference, whereby a local variable may be defined using var instead of giving a type, so long as it is unambiguous what type is meant:

var p = new Person();     // same as: Person p = new Person();
var s = "hello";          // same as: string s = "hello";
var l = new List<int>();  // same as: List<int> l = new List<int>();
var i = 10;               // same as: int i = 10;

This only works for local variables.

Operators

assignment. The left operand must be an identifier, and the right must result in a value or reference as appropriate.

+, -, /, *, %

basic arithmetic, applied to left and right operands. The + operator can also concatenate strings.

+=, -=, /=, *=, %=

arithmetic operation between left and right operands, where the left must be an identifier, to which the result is assigned.

++, --

increment and decrement operations with implicit assignment. These take just one argument, which must be an identifier of a simple data type. The value will be changed and assigned back to the identifier. These operators may be placed in either prefix or postfix positions - with the former the evaluated value of the statement will be the newly calculated value, with the latter the original value is returned.

|, ^, &, ~, |=, &=, ^=

bitwise operations: or, exclusive or, and, not. The second set include assignment and are analogous to the arithmetic versions. These can be applied to any of the simple value types. (There is of no assignment operator associated with ~ because this is a unary operator. The equivalent operation is just a = ~a).

<<, >>

bit shift operations, shifting the left operand a number of bits according the right operand.

<<=, >>=

bit shift operations, shifting the left operand a number of bits according the right operand. The left operand must be an identifier, to which the result is assigned.

==

equality test. Evaluates to a bool value dependent on whether the left and right operands are equal. In the case of value types this means their values are equal, in reference types that the objects are the same instance. An exception to this rule is the string type, which is tested for equality by value.

<, >, >=, <=, !=

inequality tests. Evaluate to a bool value dependent on whether the left and right operands are different in the manner described. These are valid for simple value data types, and the string type. For strings these operators compare the lexicographical order.

!, &&, ||

logic operations: not, and, or. These operations can be applied to Boolean values - the first taking just one value the others two.

?:

ternary conditional operator. Evaluates a condition and returns either the value of the left or the right sub-expression based on whether the condition is true or false: condition ? value if true : value if false

Operators cannot be overloaded in Vala. There are extra operators that are valid in the context of lambda declarations and other specific tasks - these are explained in their context they are applicable.

Control Structures

while (a > b) { a--; }

will decrement a repeatedly, checking before each iteration that a is greater than b.

do { a--; } while (a > b);

will decrement a repeatedly, checking after each iteration that a is greater than b.

for (int a = 0; a < 10; a++) { stdout.printf("%d\n", a); }

will initialize a to 0, then print a repeatedly until a is no longer less than 10, incrementing a after each iteration.

foreach (int a in int_array) { stdout.printf("%d\n", a); }

will print out each integer in an array, or another iterable collection. The meaning of iterable will be described later.

All of the four preceding types of loop may be controlled with the keywords break and continue. A break instruction will cause the loop to immediately terminate, while continue will jump straight to the test part of the iteration.

if (a > 0) { stdout.printf("a is greater than 0\n"); }
else if (a < 0) { stdout.printf("a is less than 0\n"); }
else { stdout.printf("a is equal to 0\n"); }

executes a particular piece of code based on a set of conditions. The first condition to match decides which code will execute, if a is greater than 0 it will not be tested whether it is less than 0. Any number of else if blocks is allowed, and zero or one else blocks.

switch (a) {
case 1:
    stdout.printf("one\n");
    break;
case 2:
case 3:
    stdout.printf("two or three\n");
    break;
default:
    stdout.printf("unknown\n");
    break;
}

A switch statement runs exactly one or zero sections of code based on the value passed to it. In Vala there is no fall through between cases, except for empty cases. In order to ensure this, each non-empty case must end with a break, return or throw statement. It is possible to use switch statements with strings.

A note for C programmers: conditions must always evaluate to a Boolean value. This means that if you want to check a variable for null or 0 you must do this explicitly: if (object != null) { } or if (number != 0) { }.

Language Elements

Functions

int function_name(int arg1, Object arg2) throws ErrorType {
    return 1;
}

this code defines a function, having the name function_name, taking two arguments, one an integer and the other an Object (the first passed by value, the second as a reference as described).

The function will return an integer, which in this case is 1.

All Vala functions are C functions, and therefore take an arbitrary number of arguments and return one value. They may approximate more return values by placing data in locations known to the calling code. Details of how to do this are in the "ref and out Arguments" section in the advanced part of this tutorial.

This particular function definition says that the function might throw an exception - this may be omitted if no exceptions are possible. Details of error handling are included later in this tutorial.

The naming convention for functions/methods in Vala is all lower case with underscores as word separators. This may be a little bit unfamiliar to C# or Java programmers who are accustomed to CamelCase or mixedCamelCase function names. But with this style you will be consistent with other Vala and C/GObject libraries.

It is not possible to have multiple functions/methods with the same name but different signature within the same scope ("method overloading"):

void draw(string text) { }
void draw(Shape shape) { }  // not possible

This is due to the fact that libraries produced with Vala are intended to be usable for C programmers as well. In Vala you would do something like this instead:

void draw_text(string text) { }
void draw_shape(Shape shape) { }

By choosing slightly different names you can avoid a name clash. In languages that support method overloading it is often used for providing convenience functions with less arguments that chain up to the most general function:

void f(int x, string s, double z) { }
void f(int x, string s) { f(x, s, 0.5); }  // not possible
void f(int x) { f(x, "hello"); }           // not possible

In this case you can use Vala's default value feature for function arguments in order to achieve a similar behaviour. You can define default values for the last arguments of a method, so that you don't have to pass them explicitly to a method call:

void f(int x, string s = "hello", double z = 0.5) { }

Some possible calls of this function might be:

f(2);
f(2, "hi");
f(2, "hi", 0.75);

However, real variable-length argument lists (a.k.a. varargs, params or ellipses) are not yet possible in Vala, at least not for self-defined functions. Only for bindings to existing C functions. Best example is stdout.printf(string format, ...).

Vala performs a basic nullability check on the function arguments and return values. If it is allowable for a function argument or a return value to be null, the type symbol should be postfixed with a ? modifier. This extra information helps the Vala compiler to perform static checks and to add runtime assertions on the preconditions of the functions, which may help in avoiding related errors such as dereferencing a null reference.

string? function_name(string? text, Foo? foo, Bar bar) {
    // ...
}

In this example text, foo and the return value may be null, however, bar may not be null.

Delegates

delegate void DelegateType(int a);

A delegate is a type of function pointer, allowing chunks of code to be passed around like objects. The example above defines a new type called "DelegateType" which represents a function taking an int and not returning a value. Any function with such a signature may be assigned to a variable of this type or passed as a function argument of this type.

void f1(int a) { stdout.printf("%d\n", a); }
...
void f2(DelegateType d, int a) {
    d(a);    // Calling a delegate
}
...
f2(f1, 5);   // Passing a function as delegate argument to another function

This code will execute the function "f2", passing in a pointer to function "f1" and the number 5. "f2" will then execute the function "f1", passing it the number.

Delegates may also be created locally. In most cases a member function can also be assigned to a delegate, e.g,

class Foo {

    public void f1(int a) {
        stdout.printf("a = %d\n", a);
    }

    delegate void DelegateType(int a);

    public static int main(string[] args) {
        Foo foo = new Foo();
        DelegateType d1 = foo.f1;
        d1(10);
        return 0;
    }
}

Anonymous Functions / Closures

f2((a) => { stdout.printf("%d\n", a); }, 5);

An anonymous function, also known as a lambda function, can be defined in Vala with the => operator.

In this example the function "f2", as defined above, is called with a reference to a unnamed function which takes one argument and prints it. Notice that neither parameter or return types are explicitly given. Instead the types are derived from the signature of the delegate that should be passed to "f2". This example is in fact functionally equivalent to the previous.

Assigning an anonymous functions to a delegate variable:

DelegateType d1 = (a) => { stdout.printf("%d\n", a); };
d1(10);

// Curly braces are optional if the block contains only one statement:
DelegateType d2 = (a) => stdout.printf("%d\n", a);
d2(20):

Since Vala 0.7.6 these lambda expressions are real closures. This means you can access the local variables of the outer method within the lambda function.

Namespaces

namespace NameSpaceName { ... }

Everything between the braces in this statement is in the namespace "NameSpaceName" and must be referenced as such. Any code outside this namespace must be either used qualified names for anything within the name of the namespace, or be in a file with an appropriate using declaration. Namespaces may contain any code except using statements.

Namespaces can be nested, either by nesting one declaration inside another, or by giving a name of the form "NameSpace1.NameSpace2".

Several other types of definition can declare themselves to be inside a namespace by following the same naming convention, e.g. class NameSpace1.Test { ... }. Note than when doing this, the final namespace of the definition will be the one the declaration is nested in plus the namespaces declared in the definition.

Structs

struct StructName {
    public int a;
}

defines a struct type, i.e. a compound value type. A Vala struct may have methods in a limited way, and therefore may have private data, meaning the explicit public descriptor is required.

struct Color {
    public double red;
    public double green;
    public double blue;
}

This is how you can initialise a struct:

// without type inference
Color c1 = Color();
Color c2 = { 0.5, 0.5, 1.0 };
Color c3 = Color() {
    red = 0.5,
    green = 0.5,
    blue = 1.0
};

// with type inference
var c4 = Color();
var c5 = Color() {
    red = 0.5,
    green = 0.5,
    blue = 1.0
};

Structs are stack allocated and copied on assignment.

Classes

class ClassName : SuperClassName, InterfaceName {
}

defines a class, i.e. a reference type. In contrast to structs, instances of classes are heap allocated. There is much more syntax related to classes, which is discussed more fully in the section about object oriented programming.

Interfaces

interface InterfaceName : SuperInterfaceName {
}

defines an interface, i.e. a non instantiable type. In order to create an instance of an interface you must first implement its abstract methods in a non-abstract class. Vala interfaces are more powerful than Java or C# interfaces. In fact, they can be used as mixins. The details of interfaces are described in the section about object oriented programming.

Code Attributes

Code Attributes instruct the Vala compiler details about how the code is supposed to work on the target platform. The use of annotations is an advanced topic which is discussed in the Advance Topics chapter.

The following example is extracted from glib-2.0.vapi. It tells us that the class string, which is used to represent string and string literals in Vala, is a compact immutable class.

[Compact]
[Immutable]
public class string {
}

The rule of thumb is never use the Code Attributes unless you are writing a painful binding for an external library.

Object Oriented Programming

Although Vala doesn't force you to work with objects, some features are not available any other way. As such, you will certainly want to program in an object-oriented style most of the time. As with most current languages, in order to define your own object types, you write a class definition.

A class definition states what data each object of its type has, what other object types it can hold references to, and what methods can be executed on it. The definition can include a name of another class which the new one should be a subclass of. An instance of a class is also an instance of all it's class's super classes, as it inherits from them all their methods and data, although it may not be able to access all of this itself. A class may also implement any number of interfaces, which are sets of method definitions that must be implemented by the class - an instance of a class is also an instance of each interface implemented by its class or super classes.

Classes in Vala may also have "static" members. This modifier allows either data or methods to be defined as belonging to the class as a whole, rather than to a specific instance of it. Such members can be accessed without possessing an instance of the class.

Basics

A simple class may be defined as follows:

public class TestClass : GLib.Object {

    /* Fields */
    public int first_data = 0;
    private int second_data;

    /* Constructor */
    public TestClass() {
        this.second_data = 5;
    }

    /* Method */
    public int function_1() {
        stdout.printf("private data: %d", this.second_data);
        return this.second_data;
    }
}

This code will define a new type (which is registered automatically with the gobject library's dynamic type system) that contains 3 members. There are two data members, the integers defined at the top, and one method called "function_1", which returns an integer. The class declaration states that this class is a subclass of GLib.Object, and therefore instances of it are also Objects, and contain all the members of that type also. The fact that this class is descended from Object also means that there are special features of Vala that can be used to easily access some of Object's features.

This class is described as public. The implication of this is that it can referenced directly by code outside of this file - if you are a C programmer of glib/gobject, you will recognise this as being equivalent to defining the class interfaces in a header file that other code can include.

The members are also all described as either public or private. The member first_data is public, so it is visible directly to any user of the class, and can be modified without the containing instance being aware of it. The second data member is private, and so can only be referenced by code belonging to this class.

The constructor initialises new instances of a class. It has the same name as the class, may take zero or more arguments and is defined without return type.

The final part of this class is a method definition. This method is to be called "function_1", and it will return an integer. As this method is not static, it can only be executed on an instance of this class, and may therefore access members of that instance. It can do this through the this reference, which always points to the instance the method is being called on. Unless there is an ambiguity, the this identifier can be omitted if wished.

You can use this new class as follows:

TestClass t = new TestClass();
t.first_data = 5;
t.function_1();

Construction

Vala supports two slightly different construction schemes: the Java/C#-style construction scheme which we will focus on for now, and the GObject-style construction scheme which will be described in a section at the end of the chapter.

Vala does not support constructor overloading for the same reasons that function/method overloading is not allowed, which means a class may not have multiple constructors with the same name. However, this is no problem because Vala supports named constructors. If you want to offer multiple constructors you may give them different name additions:

public class Button : Object {

    public Button() {
    }

    public Button.with_label(string label) {
    }

    public Button.from_stock(string stock_id) {
    }
}

Instantiation is analogous:

new Button();
new Button.with_label("Click me");
new Button.from_stock(Gtk.STOCK_OK);

You may chain constructors:

public class Demo : Object {

    public Demo() {
        stdout.printf("in Demo()\n");
    }

    public Demo.with_foo(string foo) {
        stdout.printf("in Demo.with_foo()\n");
        this.with_bar("bar");
    }

    public Demo.with_bar(string bar) {
        stdout.printf("in Demo.with_bar()\n");
        this();
    }
}

Destruction

Although Vala manages the memory for you, you might need to add your own destructor if you do manual memory management with pointers. The syntax is the same as in C# and C++:

public class T : GLib.Object {
    ~T() {
        stdout.printf("in destructor");
    }
}

Since Vala's memory management is based on reference counting instead of garbage collection, destructors are deterministic and can be used to implement the RAII pattern for resource management (closing streams, database connections, ...).

Signals

Signals are a system provided by the Object class in GLib, and made easily accessible by Vala to all descendants of Object. A signal is recognisable to C# programmers as an event, or to Java programmers as an alternative way of implementing event listeners. In short, a signal is simply a way of executing an arbitrary number of externally identically function (i.e. ones with the same signature) at approximately the same time. The actual methods of execution are internal to gobject, and not important to Vala programs.

A signal is defined as a member of a class, and appears similar to a method with no body. Signal handlers can then be added to the signal using the connect() method. Sometimes you will still see the old signal connection syntax using the += operator which will eventually become deprecated. In order to dive right in at the deep end, the following example also introduces lambda functions, a very useful way to write signal handling code in Vala:

public class Test : GLib.Object {

    public signal void sig_1(int a);

    public static int main(string[] args) {
        Test t1 = new Test();

        t1.sig_1.connect((t, a) => {
            stdout.printf("%d\n", a);
        });

        /* old signal connection syntax */
        t1.sig_1 += (t, a) => {
            stdout.printf("%d\n", a);
        };

        t1.sig_1(5);

        return 0;
    }
}

This code introduces a new class called "Test", using familiar syntax. The first member of this class is a signal, called "sig_1", which is defined as passing an integer. In the main function of this program, we first create a Test instance - a requirement since signals always belong to instances of classes. Next, we assign to our instance's "sig_1" signal a handler, which we define inline as a lambda function. The definition states that the function will receive two arguments which we call "t" and "a", but do not provide types for. We can be this terse because Vala already knows the definition of the signal and can therefore understand what types are required.

The reason there are two arguments to the handler is that whenever a signal is emitted, the object on which it is emitted is passed as the first argument to the handler. The second argument is that one that the signal says it will provide.

Finally, we get impatient and decide to emit a signal. We do this by calling the signal as though it was a method of our class, and allow gobject to take care of forwarding the message to all attached handlers. Understanding the mechanism used for this is not required to use signals from Vala.

NB: Currently the public access modifier is the only possible option - all signals can be both connected to and emitted by any piece of code.

Properties

It is good object oriented programming practice to hide implementation details from the users of your classes (information hiding principle), so you can later change the internals without breaking the public API. One practice is to make fields private and provide accessor methods for getting and setting their values (getters and setters).

If you're a Java programmer you will probably think of something like this:

class Person : Object {
    private int age = 32;

    public int get_age() {
        return this.age;
    }

    public void set_age(int age) {
        this.age = age;
    }
}

This works, but Vala can do better. The problem is that these methods are cumbersome to work with. Let's suppose that you want to increase the age of a person by one year:

var alice = new Person();
alice.set_age(alice.get_age() + 1);

This is where properties come into play:

class Person : Object {
    private int _age = 32;  // underscore prefix to avoid name clash with property

    /* Property */
    public int age {
        get { return _age; }
        set { _age = value; }
    }
}

This syntax should be familiar to C# programmers. A property has a get and a set block for getting and setting its value. value is a keyword that represents the new value that should be assigned to the property.

Now you can access the property as if it was a public field. But behind the scenes the code in the get and set blocks is executed.

var alice = new Person();
alice.age = alice.age + 1;  // or even shorter:
alice.age++;

If you only do the standard implementation as shown above then you can write the property even shorter:

class Person : Object {
    /* Property with standard getter and setter and default value */
    public int age { get; set; default = 32; }
}

With properties you can change the internal working of classes without changing the public API. For example:

static int current_year = 2525;

class Person : Object {
    private int year_of_birth = 2493;

    public int age {
        get { return current_year - year_of_birth; }
        set { year_of_birth = current_year - value; }
    }
}

This time the age is calculated on the fly from the year of birth. Note that you can do more than just simple variable access or assignment within the get and set blocks. You could do a database access, logging, cache updates, etc.

If you want to make a property read-only for the users of the class you should make the setter private:

    public int age { get; private set; default = 32; }

Or, alternatively, you can leave out the set block:

class Person : Object {
    private int _age = 32;

    public int age {
        get { return _age; }
    }
}

Properties may not only have a name but also a short description (called nick) and a long description (called blurb). You can annotate these with a special attribute:

    [Property(nick = "age in years", blurb = "This is the person's age in years")]
    public int age { get; set; default = 32; }

Properties and their additional descriptions can be queried at runtime. Some programs such as the Glade graphical user interface designer make use of this information. In this way Glade can present human readable descriptions for properties of GTK+ widgets.

Every instance of a class derived from GLib.Object has a signal called notify. This signal gets emitted every time a property of its object changes. So you can connect to this signal if you're interested in change notifications in general:

obj.notify.connect((s, p) => {
    stdout.printf("Property '%s' has changed!\n", p.name);
});

s is the source of the signal, p is the property information of type ParamSpec for the changed property. If you're only interested in change notifications of a single property you can use this syntax:

alice.notify["age"].connect((s, p) => {
    stdout.printf("age has changed\n");
});

Note that in this case you must use the string representation of the property name where underscores are replaced by dashes: my_property_name becomes "my-property-name" in this representation, which is the GObject property naming convention.

Change notifications can be disabled with a CCode attribute tag immediately before the declaration of the property:

public class MyObject : Object {
    [CCode(notify = false)]
    // notify signal is NOT emitted upon changes in the property
    public int without_notification { get; set; }
    // notify signal is emitted upon changes in the property
    public int with_notification { get; set; }
}

There's another type of properties called construct properties that are described later in the section about gobject-style construction.

Inheritance

In Vala, a class may derive from one or zero other classes. In practice this is always likely to be one, as there is no implicit inheritance as there is in languages like Java.

When defining a class that inherits from another, you create a relationship between the classes where instances of the subclass are also instances of the superclass. This means that operations on instances of the superclass are also applicable on instances of the subclass. As such, wherever an instance of the superclass is required, an instance of the subclass can be substituted.

When writing the definition of a class it is possible to exercise precise control over who can access what methods and data in the object. The following example demonstrates a range of these options:

class SuperClass : GLib.Object {

    private int data;

    public SuperClass(int data) {
        this.data = data;
    }

    protected void protected_function() {
    }

    public static void public_static_function() {
    }
}

class SubClass : SuperClass {

    public SubClass() {
        base(10);
    }
}

data is an instance data member of "SuperClass". There will be a member of this type in every instance of "SuperClass", and it is declared private so will only be accessible by code that is a part of "SuperClass".

protected_function is an instance method of "SuperClass". You will be able to execute this method only an instance of "SuperClass" or of one of its subclasses, and only from code that belongs to "SuperClass" or one of its subclasses - this latter rule being the result of the protected modifier.

public_static_function has two modifiers. The static modifier means that this method may be called without owning an instance of "SuperClass" or of one of its subclasses. As a result, this method will not have access to a this reference when it is executed. The public modifier means that this method can be called from any code, no matter its relationship with "SuperClass" or its subclasses.

Given these definitions, an instance of "SubClass" will contain all three members of "SuperClass", but will only be able to access the non-private members. External code will only be able to access the public method.

With base a constructor of a subclass can chain up to a constructor of its base class.

Abstract Classes

There is another modifier for methods, called abstract. This modifier allows you to describe a method that is not actually implemented in the class. Instead, it must be implemented by subclasses before it can be called. This allows you to define operations that can be called on all instances of a type, whilst ensuring that all more specific types provide their own version of the functionality.

A class containing abstract methods must be declared abstract as well. The result of this is to prevent any instantiation of the type.

public abstract class Animal : Object {

    public void eat() {
        stdout.printf("*chomp chomp*\n");
    }

    public abstract void say_hello();
}

public class Tiger : Animal {

    public override void say_hello() {
        stdout.printf("*roar*\n");
    }
}

public class Duck : Animal {

    public override void say_hello() {
        stdout.printf("*quack*\n");
    }
}

The implementation of an abstract method must be marked with override. Properties may be abstract as well.

Interfaces / Mixins

A class in Vala may implement any number of interfaces. Each interface is a type, much like a class, but one that cannot be instantiated. By "implementing" one or more interfaces, a class may declare that its instances are also instances of the interface, and therefore may be used in any situation where an instance of that interface is expected.

The procedure for implementing an interface is the same as for inheriting from classes with abstract methods in - if the class is to be useful it must provide implementations for all methods that are described but not yet implemented.

A simple interface definition looks like:

public interface ITest : GLib.Object {
    public abstract int data_1 { get; set; }
    public abstract void function_1();
}

This code describes an interface "ITest" which requires GLib.Object as parent and contains two members. "data_1" is a property, as described above, except that it is declared abstract. Vala will therefore not implement this property, but instead require that classes implementing this interface have a property called "data_1" that has both get and set accessors - it is required that this be abstract as an interface may not have any data members. The second member "function_1" is a method. Here it is declared that this method must be implemented by classes that implement this interface.

The simplest possible full implementation of this interface is:

public class Test1 : GLib.Object, ITest {
    public int data_1 { get; set; }
    public void function_1() {
    }
}

And may be used as follows:

var t = new Test1();
t.function_1();

ITest i = t;
i.function_1();

Interfaces in Vala may not inherit from other interfaces, but they may declare other interfaces to be prerequisites, which works in roughly the same way. For example, it may be desirable to say that any class that implements a "List" interface must also implement a "Collection" interface. The syntax for this is exactly the same as for describing interface implementation in classes:

public interface List : Collection {
}

This definition of "List" may not be implemented in a class without "Collection" also being implemented, and so Vala enforces the following style of declaration for a class wishing to implement "List", where all implemented interfaces must be described:

public class ListClass : GLib.Object, Collection, List {
}

Vala interfaces may also have a class as a prerequisite. If a class name is given in the list of prerequisites, the interface may only be implemented in classes that derive from that prerequisite class. This is often used to ensure that an instance of an interface is also a GLib.Object subclass, and so the interface can be used, for example, as the type of a property.

The fact that interfaces can not inherit from other interfaces is mostly only a technical distinction - in practice Vala's system works the same as other languages in this area, but with the extra feature of prerequisite classes.

There's another important difference between Vala interfaces and Java/C# interfaces: Vala interfaces may have non-abstract methods! Vala actually allows method implementations in interfaces, hence the requirement that abstract methods be declared abstract. Due to this fact Vala interfaces can act as mixins. This is a restricted form of multiple inheritance.

Polymorphism

Polymorphism describes the way in which the same object can be used as though it were more than one distinct type of thing. Several of the techniques already described here suggest how this is possible in Vala: An instance of a class may be used as in instance of a superclass, or of any implemented interfaces, without any knowledge of its actual type.

A logical extension of this power is to allow a subtype to behave differently to its parent type when addressed in exactly the same way. This is not a very easy concept to explain, so I'll begin with an example of what will happen if you do not directly aim for this goal:

class SuperClass : GLib.Object {
    public int function_1() {
        stdout.printf("SuperClass.function_1()\n");
    }
}

class SubClass : SuperClass {
    public int function_1() {
        stdout.printf("SubClass.function_1()\n");
    }
}

These two classes both implement a function called "function_1", and "SubClass" therefore contains two functions called "function_1", as it inherits one from "SuperClass". Each of these may be called as the following code shows:

SubClass o1 = new SubClass();
o1.function_1();
SuperClass o2 = o1;
o2.function_1();

This will actually result in two different functions being called. The second line believes "o1" to be a "SubClass" and will call that class's version of the function. The fourth line believes "o2" to be a "SuperClass" and will call that class's version of the function.

The problem this example exposes, is that any code holding a reference to "SuperClass" will call the functions actually described in that class, even in the actual object is of a subclass. The way to change this behaviour is using virtual functions. Consider the following rewritten version of the last example:

class SuperClass : GLib.Object {
    public virtual void function_1() {
        stdout.printf("SuperClass.function_1()\n");
    }
}

class SubClass : SuperClass {
    public override void function_1() {
        stdout.printf("SubClass.function_1()\n");
    }
}

When this code is used in the same way as before, "SubClass"'s "function_1" will be called twice. This is because we have told the system that "function_1" is a virtual function, meaning that if it is overridden in a subclass, that new version will always be executed on instances of that subclass, regardless of the knowledge of the caller.

This distinction is probably familiar to programmers of some languages, such as C++, but it is in fact the opposite of Java style languages, in which steps must be taken to prevent a method being virtual.

You will probably now also have recognised that when method is declared as abstract it must also be virtual. Otherwise, it would not be possible to execute that function given an apparent instance of the type it was declared in. When implementing an abstract function in a subclass, you may therefore choose to declare the implementation as override, thus passing on the virtual nature of the method, and allowing subtypes to do the same if they desire.

It's also possible to implement interface methods in such a way that subclasses can change the implementation. The process in this case is for the initial implementation to declare the function implementation to be virtual, and then subclasses can override as required.

When writing a class, it is common to want to use functionality defined in a class you have inherited from. This is complicated where the function name is used more than one in the inheritance tree for your class. For this Vala provides the base keyword. The most common case is where you have overridden a virtual method to provide extra functionality, but still need the parent class' method to be called. The following example shows this case:

public override void function_name() {
    base.function_name();
    extra_task();
}

Run-Time Type Information

Since Vala classes are registered at runtime and each instance carries its type information you can dynamically check the type of an object with the is operator:

bool b = object is SomeTypeName;

You can get the type information of Object instances with the get_type() method:

Type type = object.get_type();
stdout.printf("%s\n", type.name());

With the typeof() operator you can get the type information of a type directly. From this type information you can later create new instances with Object.new():

Type type = typeof(Foo);
Foo foo = (Foo) Object.new(type);

Dynamic Type Casting

For the dynamic cast, a variable is casted by a postfix expression as DesiredTypeName. Vala will include a runtime type checking to ensure this casting is reasonable - if it is an illegal casting, null will be returned. However, this requires both the source type and the target type to be referenced class types.

For example,

Button b = widget as Button;

If for some reason the class of the widget instance is not the Button class or one of its subclasses or does not implement the Button interface, b will be null. This cast is equivalent to:

Button b = (widget is Button) ? (Button) widget : null;

Generics

Vala includes a runtime generics system, by which a particular instance of a class can be restricted with a particular type or set of types chosen at construction time. This restriction is generally used to require that data stored in the object must be of a particular type, for example in order to implement a list of objects of a certain type. In that example, Vala would make sure that only objects of the requested type could be added to the list, and that on retrieval all objects would be cast to that type.

In Vala, generics are handled while the program is running. When you define a class that can be restricted by a type, there still exists only one class, with each instance customised individually. This is in contrast to C++ which creates a new class for each type restriction required - Vala's is similar to the system used by Java. This has various consequences, most importantly: that static members are shared by the type as a whole, regardless of the restrictions placed on each instance; and that given a class and a subclass, a generic refined by the subclass can be used as a generic refined by the class.

The following code demonstrates how to use the generics system to define a minimal wrapper class:

public class Wrapper<G> : GLib.Object {
    private G data;

    public void set_data(G data) {
        this.data = data;
    }

    public G get_data() {
        return this.data;
    }
}

This "Wrapper" class must be restricted with a type in order to instantiate it - in this case the type will be identified as "G", and so instances of this class will store one object of "G" type, and have functions to set or get that object. (The reason for this specific example is to provide reason explain that currently a generic class cannot use properties of its restriction type, and so this class has simple get and set methods instead.)

In order to instantiate this class, a type must be chosen, for example the built in string type (in Vala there is no restriction on what type may be used in a generic). To create an briefly use this class:

var wrapper = new Wrapper<string>();
wrapper.set_data("test");
var data = wrapper.get_data();

As you can see, when the data is retrieved from the wrapper, it is assigned to an identifier with no explicit type. This is possible because Vala knows what sort of objects are in each wrapper instance, and therefore can do this work for you.

The fact that Vala does not create multiple classes out of your generic definition means that you can code as follows:

class TestClass : GLib.Object {
}

void accept_object_wrapper(Wrapper<Glib.Object> w) {
}

...
var test_wrapper = new Wrapper<TestClass>();
accept_object_wrapper(test_wrapper);
...

Since all "TestClass" instances are also Objects, the "accept_object_wrapper" function will happily accept the object it is passed, and treat its wrapped object as though it was a GLib.Object instance.

GObject-Style Construction

As pointed out before, Vala supports an alternative construction scheme that is slightly different to the one described before, but closer to the way GObject construction works. Which one you prefer depends on whether you come from the GObject side or from the Java or C# side. The gobject-style construction scheme introduces some new syntax elements: construct properties, a special Object(...) call and a construct block. Let's take a look at how this works:

public class Person : Object {

    /* Construction properties */
    public string name { get; construct; }
    public int age { get; construct set; }

    public Person(string name) {
        Object(name: name);
    }

    public Person.with_age(string name, int years) {
        Object(name: name, age: years);
    }

    construct {
        // do anything else
        stdout.printf("Welcome %s\n", this.name);
    }
}

With the gobject-style construction scheme each construction method only contains an Object(...) call for setting so-called construct properties. The Object(...) call takes a variable number of named arguments in the form of property: value. These properties must be declared as construct properties. They will be set to the given values and afterwards all construct {} blocks in the hierarchy from GLib.Object down to our class will be called.

The construct block is guaranteed to be called when an instance of this class is created, even if it is created as a subtype. It does neither have any parameters, nor a return value. Within this block you can call other methods and set member variables as needed.

Construct properties are defined just as get and set properties, and therefore can run arbitrary code on assignment. If you need to do initialisation based on a single construct property, it is possible to write a custom construct block for the property, which will be executed immediately on assignment, and before any other construction code.

If a construct property is declared without set it is a so-called construct only property, which means it can only be assigned on construction, but no longer afterwards. In the example above name is such a construct only property.

Here's a summary of the various types of properties together with the nomenclature usually found in the documentation of gobject-based libraries:

    public int a { get; private set; }    // Read
    public int b { private get; set; }    // Write
    public int c { get; set; }            // Read / Write
    public int d { get; set construct; }  // Read / Write / Construct
    public int e { get; construct; }      // Read / Write / Construct Only

Advanced Features

Assertions and Contract Programming

With assertions a programmer can check assumptions at runtime. The syntax is assert(condition). If an assertion fails the program will terminate with an appropriate error message.

You might be tempted to use assertions in order to check function arguments for null. However, this is not necessary, since Vala does that implicitly for all arguments that are not marked with ? as being nullable.

void function_name(Foo foo, Bar bar) {
    /* Not necessary, Vala does that for you:
    assert(foo != null);
    assert(bar != null);
    */
}

Vala supports basic contract programming features. A function/method may have preconditions (requires) and postconditions (ensures) that must be fulfilled at the beginning or the end of a method respectively:

double function_name(int x, double d)
        requires (x > 0 && x < 10)
        requires (d >= 0.0 && d <= 1.0)
        ensures (result >= 0.0 && result <= 10.0)
{
    return d * x;
}

result is a special variable representing the return value.

Error Handling

GLib has a system for managing runtime exceptions called GError. Vala translates this into a form familiar to modern programming languages, but its implementation means it is not quite the same as in Java or C#. It is important to consider when to use this type of error handling - GError is very specifically designed to deal with recoverable runtime errors, i.e. factors that are not known until the program is run on a live system, and that are not fatal to the execution. You should not use GError for problems that can be foreseen, such as reporting that an invalid value has been passed to a function. If a function, for example, requires a number greater than 0 as a parameter, it should fail on negative values using contract programming techniques such as preconditions or assertions described in the previous section.

Vala errors are so-called checked exceptions, which means that errors must get handled at some point. However, if you don't catch an error the Vala compiler will only issue a warning without stopping the compilation process.

Using exceptions (or errors in Vala terminology) is a matter of:

1) Declaring that a function may raise an error:

void function_1(int a) throws IOError { ... }

2) Throwing the error when appropriate:

if (!check_file()) {
    throw new IOError.FILE_NOT_FOUND("Requested file could not be found.");
}

3) Catching the error from the calling code:

try {
    function_1(-1);
} catch (IOError e) {
    stdout.printf("Error: %s\n", e.message);
}

All this appears more or less as in other languages, but defining the types of errors allowed is fairly unique. Errors have three components, known as "domain", "code" and message. Messages we have already seen, it is simply a piece of text provided when the error is created. Error domains describe the type of problem, and equates to a subclass of "Exception" in Java or similar. In the above examples we imagined an error domain called "IOError". The third part, the error code is a refinement describing the exact variety of problem encountered. Each error domain has one or more error codes - in the example there is a code called "FILE_NOT_FOUND".

The way to define this information about error types is related to the implementation in glib. In order for the examples here to work, a definition is needed such as:

errordomain IOError {
    FILE_NOT_FOUND
}

When catching an error, you give the error domain you wish to catch errors in, and if an error in that domain is thrown, the code in the handler is run with the error assigned to the supplied name. From that error object you can extract the error code and message as needed. If you want to catch errors from more than one domain, simply provide extra catch blocks. There is also an optional block that can be placed after a try and any catch blocks, called finally. This code is to be run always at the end of the section, regardless of whether an error was thrown or any catch blocks were executed, even if the error was in fact no handled and will be thrown again. This allows, for example, any resources reserved in the try block be freed regardless of any errors raised. A complete example of these features:

errordomain ErrorType1 {
    CODE_1A
}

errordomain ErrorType2 {
    CODE_2A
}

public class Test : GLib.Object {
    public static void thrower() throws ErrorType1, ErrorType2 {
        throw new ErrorType1.CODE_1A("Error");
    }

    public static void catcher() throws ErrorType2 {
        try {
            thrower();
        } catch (ErrorType1 e) {
            // Deal with ErrorType1
        } finally {
            // Tidy up
        }
    }

    public static int main(string[] args) {
        try {
            catcher();
        } catch (ErrorType2 e) {
            // Deal with ErrorType2
        }
        return 0;
    }
}

This example has two error domains, both of which can be thrown by the "thrower" function. Catcher can only throw the second type of error, and so must handle the first type if "thrower" throws it. Finally the "main" function will handle any errors from "catcher".

ref and out Arguments

A function in Vala is passed zero or more parameters. The default behaviour when a function is called is as follows:

Any value type parameters are copied to a location local to the function as it executes.
Any reference type parameters are not copied, instead just a reference to them is passed to the function.

This behaviour can be changed with the modifiers 'ref' and 'out'.

'out' from the caller side: you may pass an uninitialised variable to the method and you may expect it to be initialised after the method returns
'out' from callee side: the parameter is considered uninitialised and you have to initialise it
'ref' from caller side: the variable you're passing to the method has to be initialised and it may be changed or not by the method
'ref' from callee side: the parameter is considered initialised and you may change it or not

void function_1(int a, out int b, ref int c) { ... }
void function_2(Object o, out Object p, ref Object q) { ... }

These functions can be called as follows:

int a = 1;
int b;
int c = 3;
function_1(a, out b, ref c);

Object o = new Object();
Object p;
Object q = new Object();
function_2(o, out p, ref q);

The treatment of each variable will be:

"a" is of a value type. The value will be copied into a new memory location local to the function, and so changes to it will not be visible to the caller.
"b" is also of a value type, but passed as an out parameter. In this case, the value is not copied, instead a pointer to the data is passed to the function, and so any change to the function parameter will be visible to the calling code.
"c" is treated in the same way as "b", the only change is in the signalled intent of the function.
"o" is of a reference type. The function is passed a reference to the same object as the caller has. The function can therefore change that object, but if it reassigns to the parameter, that change will not be visible to the caller.
"p" is of the same type, but passed as an out parameter. This means that the function will receive a pointer to the reference to the object. It may therefore replace the reference with a reference to another object, and when the function returns the caller will instead own a reference to that other object. When you use this type of parameter, if you do not assign a new reference to the parameter, it will be set to null.
"q" is again of the same type. This case is treated like "p" with the important differences that the function may choose not to change the reference, and may access the object referred to. Vala will ensure that in this instance "q" actually refers to any object, and is not set to null.

Debugging

For demonstration purposes we will create a buggy program by intentionally dereferencing a null reference, which will result in a segmentation fault:

class Foo : Object {
    public int field;
}

void main() {
    Foo? foo = null;
    stdout.printf("%d\n", foo.field);
}

$ valac debug-demo.vala
$ ./debug-demo
Segmentation fault

So how do we debug this program? The -g command line option tells the Vala compiler to include Vala source code line information in the compiled binary, --save-temps keeps the temporary C source files:

$ valac -g --save-temps debug-demo.vala

Vala programs can be debugged with the GNU Debugger gdb or one of its graphical front-ends, e.g. Nemiver.

$ nemiver debug-demo

A sample gdb session:

$ gdb debug-demo
(gdb) run
Starting program: /home/valacoder/debug-demo

Program received signal SIGSEGV, Segmentation fault.
0x0804881f in _main () at debug-demo.vala:7
7           stdout.printf("%d\n", foo.field);
(gdb)

libgee: Working with Collections

Gee is a library of collection classes, written in Vala. The classes should all be familiar to users of libraries such as Java's Foundation Classes. Gee consists of a set of interfaces and various types that implement these in different ways. Although Gee is not a part of Vala as such, it is used internally in Vala, and is sufficiently closely related that Vala supports certain special syntax for Gee related operations.

If you want to use libgee in your own application, don't use the one internally used (and provided) by libvala. Instead, install the library separately on your system. Gee can be obtained from http://live.gnome.org/Libgee.

The fundamental types of collection are:

Lists: Ordered collections of items, accessible by numeric index.
Sets: Unordered collections of distinct.
Maps: Unordered collection of items, accessible by index of arbitrary type.

All the lists and sets in the library implement the "Collection" interface, and all maps the "Map" interface. Lists also implement "List" and sets "Set". These common interfaces means not only that all collections of a similar type can be used interchangeably, but also that new collections can be written using the same interfaces, and therefore used with existing code.

Also common to every "Collection" type is the "Iterable" interface. This means that any object in this category can be iterated through using a standard set of functions, or directly in Vala using the foreach syntax.

All classes and interfaces use the Generics system. This means that they must be instantiated with a particular type of set of types that they will contain. The system will ensure that only the intended types can be put into the collections, and that when objects are retrieved they are returned as the correct type.

The Gee classes are:

ArrayList<G>

Implementing: Gee.Iterable<G>, Gee.Collection<G>, Gee.List<G>

An ordered list of items of type G backed by a dynamically resizing array. This type is very fast for accessing data, but potentially slow at inserting items anywhere other than at the end, or at inserting items when the internal array is full.

HashMap<K,V>

Implementing: Gee.Map<K,V>

A 1:1 map from elements of type K to elements of type V. The mapping is made by computing a hash value for each key - this can be customised by providing pointers to function for hashing and testing equality of keys in specific ways.

For example, if the keys are to be the built in string type, the map could be created using functions from Glib, as:

var map = new Gee.HashMap<string, Object>(GLib.str_hash, GLib.str_equal);

HashSet<G>

Implementing: Gee.Iterable<G>, Gee.Collection<G>, Gee.Set<G>

A set of elements of type G. Duplicates are detected by computing a hash value for each key - this can be customised by providing pointers to function for hashing and testing equality of keys in specific ways.

ReadOnlyCollection<G>

Implementing: Gee.Iterable<G>, Gee.Collection<G>

A wrapper for another collection with elements of type G. The wrapper has the same interface as its contained collection, but will not allow any form of modification, or any access to the contained collection.

ReadOnlyList<G>

Implementing: Gee.Iterable<G>, Gee.Collection<G>, Gee.List<G>

A wrapper for another list with elements of type G. The wrapper has the same interface as its contained list, but will not allow any form of modification, or any access to the contained list. This class behaves the same as "ReadOnlyCollection", except that it also implements the "List" interface.

ReadOnlyMap<K,V>

Implementing: Gee.Map<K,V>

A wrapper for another map of key type K and value type G. The wrapper has the same interface as its contained map, but will not allow any form of modification, or any access to the contained map.

ReadOnlySet<G>

Implementing: Gee.Iterable<G>, Gee.Collection<G>, Gee.Set<G>

A wrapper for another set of elements of type G. The wrapper has the same interface as its contained map, but will not allow any form of modification, or any access to the contained set.

Multi-Threading

Threads in Vala

A program written in Vala may have more that one thread of execution, allowing it it do more than one thing at a time. Exactly how this is managed is outside of Vala's scope - threads may be sharing a single processor core or not, depending on the environment.

A thread in Vala is not defined at compile time, instead it is simply a portion of Vala code that is requested at runtime to be executed as a new thread. This is done using the static functions of the Thread class in GLib, as shown in the following (very simplified) example:

public class Threading : GLib.Object {

    public static void* thread_func() {
        stdout.printf("Thread running.\n");
        return null;
    }

    public static int main(string[] args) {
        if (!Thread.supported()) {
            stderr.printf("Cannot run without threads.\n");
            return 1;
        }

        try {
            Thread.create(thread_func, false);
        } catch (ThreadError e) {
            return 1;
        }

        return 0;
    }
}

This short program will request a new thread be created an executed. The code to be run being that in "thread_func". Also note the test at the start of the main function - a Vala program will not be able to use threads unless compiled appropriately, so it you build this example in the usual way, it will just display an error and stop running. Being able to check for thread support at runtime allows a program to be built to run either with or without threads if that is wanted. In order to build with thread support, run:

$ valac --thread -o thread-test threading.vala

This will both include required libraries and make sure the threading system is initialised whenever possible.

The program will now run without segmental faults, but it will still not act as expected. Without any sort of event loop, a Vala program will terminate when its primary thread (the one created to run "main") ends. In order to control this behaviour, you can allow threads to cooperate. This can be done powerfully using event loops and asynchronous queues, but in this introduction to threading we will just show the basic capabilities of threads.

It is possible for a thread to tell the system that it currently has no need to execute, and thereby suggest that another thread should be run instead, this is done using the static method Thread.yield(). If this statement were placed at the end of the above "main" function, the runtime system will pause the main thread for an instant and check if there are other threads that can be run - on finding the newly created thread in a runnable state, it will run that instead until it is finished - and the program will act is it appears it should. However, there is no guarantee that this will happen still. The system is able to decide when threads run, and as such might not allow the new thread to finish before the primary thread is restarted and the program ends.

In order to wait for a thread to finish entirely there is the static function Thread.join(). Calling this with a Thread as its argument causes the calling thread to wait for the other thread to finish before proceeding. It also allows a thread to receive the return value of another, if that is useful. To implement joining threads:

try {
    unowned Thread thread = Thread.create(thread_func, true);
    thread.join();
} catch (ThreadError e) {
    return 1;
}

This time, when we create the thread we give true as the last argument. This marks the thread as "joinable". We also remember the value returned from the creation - an unowned reference to a Thread object (unowned references are explained later and are not vital to this section.) With this reference it is possible to join the new thread to the primary thread. With this version of the program it is guaranteed that the newly created thread will be allowed to fully execute before the primary thread continues and the program terminates.

All these examples have a potential problem, in that the newly created thread doesn't know the context in which it should run. In C you would supply the thread creation function with some data, in Vala instead you would normally pass an instance method to Thread.create, instead of a static method.

Resource Control

Whenever more than one thread of execution is running simultaneously, there is a chance that data are accessed simultaneously. This can lead to race conditions, where the outcome depends on when the system decides to switch between threads.

In order to control this situation, you can use the lock keyword to ensure that certain blocks of code will not be interrupted by other threads that need to access the same data. The best way to show this is probably with an example:

public class Test : GLib.Object {

    private int a { get; set; }

    public void action_1() {
        lock (a) {
            int tmp = a;
            tmp++;
            a = tmp;
        }
    }

    public void action_2() {
        lock (a) {
            int tmp = a;
            tmp--;
            a = tmp;
        }
    }
}

This class defines two functions, where both need to change the value of "a". If there were no lock statements here, it would be possible for the instructions in these functions to be interweaved, and the resulting change to "a" would be effectively random. As there are the lock statements here, Vala will guarantee that if one thread has locked "a", another thread that needs the same lock will have to wait its turn.

In Vala it is only possible to lock members of the object that is executing the code. This might appear to be a major restriction, but in fact the standard use for this technique should involve classes that are individually responsible for controlling a resource, and so all locking will indeed be internal to the class. Likewise, in above example all accesses to "a" are encapsulated in the class.

The Main Loop

GLib includes a system for running an event loop, in the classes around MainLoop. The purpose of this system is to allow you to write a program that waits for events and responds to them, instead of having to constantly check conditions. This is the model that GTK+ uses, so that a program can wait for user interaction without having to have any currently running code.

The following program creates and starts a MainLoop, and then attaches a source of events to it. In this case the source is a simple timer, that will execute the given function after 2000ms. The function will in fact just stop the main loop, which will in this case exit the program.

void main() {

    var loop = new MainLoop(null, false);
    var time = new TimeoutSource(2000);

    time.set_callback(() => {
        stdout.printf("Time!\n");
        loop.quit();
        return false;
    });

    time.attach(loop.get_context());

    loop.run();
}

When using GTK+, a main loop will be created automatically, and will be started when you call the `Gtk.main()' function. This marks the point where the program is ready to run and start accepting events from the user or elsewhere. The code in GTK+ is equivalent to the short example above, and so you may add event sources in much the same way, although of course you need to use the GTK+ functions to control the main loop.

void main(string[] args) {

    Gtk.init(ref args);
    var time = new TimeoutSource(2000);

    time.set_callback(() => {
        stdout.printf("Time!\n");
        Gtk.main_quit();
        return false;
    });

    time.attach(null);

    Gtk.main();
}

A common requirement in GUI programs is to execute some code as soon as possible, but only when it will not disturb the user. For this, you use IdleSource instances. These send events to the programs main loop, but request they only be dealt with when there is nothing more important to do.

For more information about event loops, see the GLib and GTK+ documentation.

Asynchronous Functions

With asynchronous functions it is possible to do programming without any blocking. Since version 0.7.6 Vala provides a special syntax for asynchronous programming.

Syntax and Example

An asynchronous method is defined with the async modifier. You can call an async method with async_function_name.begin() from a synchronous method.

From async methods other async methods can be called with the yield keyword. This will make the first async method be suspended until the other async method returns its results (see example).

All this is implicitly done via callbacks with AsyncResult. Therefore all async stuff in Vala depends on GIO.

// Example with GIO asynchronous methods:

async void list_dir() {
    var dir = File.new_for_path (Environment.get_home_dir());
    try {
        var e = yield dir.enumerate_children_async(FILE_ATTRIBUTE_STANDARD_NAME,
                                                   0, Priority.DEFAULT, null);
        while (true) {
            var files = yield e.next_files_async(10, Priority.DEFAULT, null);
            if (files == null) {
                break;
            }
            foreach (var info in files) {
                print("%s\n", info.get_name());
            }
        }
    } catch (Error e) {
        warning("Error: %s\n", e.message);
    }
}

void main() {
    list_dir.begin();

    var loop = new MainLoop(null, false);
    loop.run();
}

list_dir() will not block. Within list_dir() the async functions enumerate_children_async() and next_files_async() are called with the yield keyword. list_dir() continues executing as soon as a result is returned to it.

Writing Your Own Async Methods

The previous example used async GIO methods to demonstrate the usage of .begin() and yield in async methods. But it is also possible to write your own async methods.


// Example with custom asynchronous method:

class Test : Object {
    public async string test_string(string s, out string t) {
        assert(s == "hello");
        Idle.add(test_string.callback);
        yield;
        t = "world";
        return "vala";
    }
}

async void run(Test test) {
    string t, u;
    u = yield test.test_string("hello", out t);
    print("%s %s\n", u, t);
    main_loop.quit();
}

MainLoop main_loop;

void main() {
    var test = new Test();

    run.begin(test);

    main_loop = new MainLoop(null, false);
    main_loop.run();
}

The .callback call is used to implicitly register a _finish function for the async method. This is used with the bare yield statement.

    // add your functions callback
    Idle.add(async_function.callback);
    yield;
    // return the result
    return a_result_of_some_type;

After the yield; the result can be retuned. Implicitly, this is done in an AsyncResult in a callback function. The .callback is very much like the concept of continuation in certain programming languages (e.g Scheme) except that in Vala it represents the context immediately following the next yield statement.

end() is a syntax for the *_finish function. It takes an AsyncResult and returns the real result or throws an error (if the async function does). It's called like

    async_function.end(result)

in the async callback.

Ownership Issues

Unowned and Weak References

Normally when creating an object in Vala you are returned a reference to it. Specifically this means that as well as being passed a pointer to the object in memory, it is also recorded in the object itself that this pointer exists. Similarly, whenever another reference to the object is created, this is also recorded. As an object knows how many references there are to it, it can automatically be removed when needed. This is the basis of Vala's memory management.

Unowned(weak) References conversely are not recorded in the object they reference. This allows the object to be removed when it logically should be, regardless of the fact that there might be still references to it. The usual way to achieve this is with a function defined to return a weak or unowned reference, e.g.:

public static class Test {
    static Object o;

    public static weak Object get_weak_ref() {
        o = new Object();
        return o;
    }
}

or equivalently

public static class Test {
    static Object o;

    public static unowned Object get_weak_ref() {
        o = new Object();
        return o;
    }
}

When calling this function, in order to collect a reference to the returned object, you must expect to receive a weak reference:

unowned Object o = get_weak_ref();

weak Object o = get_weak_ref();

The reason for this seemingly overcomplicated example because of the concept of ownership.

If the Object "o" was not stored in the class, then when the function "get_weak_ref" returned, "o" would become unowned (i.e. there would be no references to it). If this were the case, the object would be deleted and the function would never return a valid reference.
If the return value was not defined as unowned, the ownership would pass to the calling code. The calling code is, however, expecting an unowned reference, which cannot receive the ownership.

If the calling code is written as

Object o = get_weak_ref();

Vala will try to either obtain a reference of or a duplicate of the instance the unowned reference pointing to.

In contrast to normal methods, properties always have unowned return value. That means you can't return a new object created within the get method. That also means, you can't use an owned return value from a method call. The somewhat irritating fact is because of that a property value is owned by the object that HAS this property. A call to obtain this property value should not steal or reproduce(by duplicating, or increasing the reference count of) the value from the object side.

As such, the following example will result in a compilation error

public Object property {
    get {
        return new Object();   // WRONG: property returns an unowned reference,
                               // the newly created object will be deleted when
                               // the getter scope ends the caller of the
                               // getter ends up receiving an invalid reference
                               // to a deleted object.
    }
}

nor can you do this

public string property {
    get {
        return getter_method();   // WRONG: for the same reason above.
    }
}

public string getter_method() {
    return "some text"; // "some text" is duplicated and returned at this point.
}

on the other hand, this is perfectly fine

public string property {
    get {
        return getter_method();   // GOOD: getter_method returns an unowned value
    }
}

public unowned string getter_method() {
    return "some text";
    // Don't be alarmed that the text is not assigned to any strong variable.
    // Literal strings in Vala are always owned by the program module itself,
    // and exist as long as the module is in memory
}

The weak or unowned modifier can be used to make automatic property's storage weak or unowned. That means

public weak Object property { get; private set; }

is identical to

private weak Object _property;

public Object property {
    get { return _property; }
}

The keyword owned can be used to specifically ask a property to return a owned reference of the value, therefore causing the property value be reproduced in the object side. Think twice before adding the owned keyword. Is it a property or simply a get_xxx function? There may also be problems in your design. Anyways, the following code is a correct segment,

public owned Object property { owned get { return new Object(); }}

Unowned references play a similar role to pointers which are described next. They are however much simpler to use than pointers, as they can be easily converted to normal references. However, in general they should not be widely used in the programs unless you know what you are doing.

caller \ callee		weak
	callee ref, caller unref	caller ref&unref
weak	forbidden	no refs

Transferring the Ownership

The keyword owned is used to transfer ownership (in an older version of Vala, it was #).

As a prefix of a parameter type, it means that ownership of the object is transferred into this code context.
As an type conversion operator, it can be used to avoid duplicating non-reference counting classes, which is usually impossible in Vala. For example,

Foo foo = (owned) bar;

or in older version,

Foo foo = #bar;

This means that bar will be set to null and foo inherits the reference/ownership of the object bar references.

Pointers

Pointers are Vala's way of allowing manual memory management. Normally when you create an instance of a type you receive a reference to it, and Vala will take care of destroying the instance when there are no more references left to it. By requesting instead a pointer to an instance, you take responsibility for destroying the instance when it is no longer wanted, and therefore get greater control over how much memory is used.

This functionality is not necessarily needed most of the time, as modern computers are usually fast enough to handle reference counting and have enough memory that small inefficiencies are not important. The times when you might resort to manual memory management are:

When you specifically want to optimise part of a program.
When you are dealing with an external library that does not implement reference counting for memory management (probably meaning one not based on gobject.)

In order to create an instance of a type, and receive a pointer to it:

Object* o = new Object();

In order to access members of that instance:

o->function_1();
o->data_1;

In order to free the memory pointed to:

delete o;

Non-Object classes

Classes defined as not being descended from GLib.Object are treated as a special case. They are derived directly from GLib's type system and therefore much lighter in weight. In a more recent Vala compiler, one can also implement interfaces, signals and properties with these classes.

One obvious case of using these non-object classes stays in the GLib bindings. Because GLib is at a lower level than GObject, most classes defined in the binding are of this kind. Also, as mentioned before, the lighter weight of non-object classes make them useful in many practical situations (e.g. the Vala compiler itself). However the detailed usage of non-Object classes are outside the scope of this tutorial. Be aware that these classes are fundamentally different from structs.

Libraries

At the system level, a Vala library is exactly a C library, and so the same tools are used. In order to make the process simpler, and so that the Vala compiler can understand the process there is then an extra level of Vala specific information.

A "Vala library" is therefore, the system part:

A system library (e.g. libgee.so)
A pkgconfig entry (e.g. gee-1.0.pc)

Both of which are installed in the standard locations. And the Vala specific files:

A VAPI file (e.g. gee-1.0.vapi)
An optional dependency file (e.g. gee-1.0.deps)

These files are explained later in this section. It should be noted that the library names are the same in the Vala specific files as in the pkgconfig files.

Using Libraries

Using a library in Vala is largely automated if you use the valac compiler. The Vala specific library files make up what is known as a package. You tell the compiler that a package is needed by your program as follows:

$ valac --pkg gee-1.0 -o test test.vala

These command will mean your program can use any of the definitions in the gee-1.0.vapi file, and also any in any of the packages that gee-1.0 depends on. These dependencies would be be listed in gee-1.0.deps if there were any. In this example valac is set to build all the way to binary, and will therefore incorporate information from pkg-config to link the correct libraries. This is why the pkg-config names are also used for Vala package names.

Packages are generally used with namespaces, but they are not technically related. This means that even though your application is built with reference to the package, you must still include the required using statements in each file as appropriate, or else use the fully defined names of all symbols.

It is also possible to treat a local library (one that is not installed) as a package. For comparison, Vala itself uses an internal version of Gee. When valac is built it creates a VAPI file of this internal library and uses it roughly as follows:

$ valac --vapidir ../gee --pkg gee ...

For details of how to generate this library, see the next section or the example.

Creating a Library

Vala is not yet capable of directly create dynamic or static libraries. To create an library, proceed with the -c (compile only) switch and link the object files with your favourite linker, i.e. libtool or ar.

$ valac -c ...(source files)
$ ar cx ...(object files)

or by compiling the intermediate C code with gcc

$ valac -C ..(source files)
$ gcc -o my-best-library.so --shared -fPIC ...(compiled c code files)...

Example

The following is an example of how to write a simple library in Vala, and also to compile and test it locally without having to install it first.

Save the following code to a file "test.vala". This is the actual library code, containing the functions we want to call from our main program.

using GLib;

public class MyLib : Object {

    public void hello() {
        stdout.printf ("Hello World, MyLib\n");
    }

    public int sum(int x, int y) {
        int result = x + y;
        return result;
    }
}

Use the next command to generate "test.c", "test.h" and "test.vapi" files. These are the C versions of the library to be compiled, and the VAPI file representing the library's public interface.

$ valac -C -H test.h --library test test.vala --basedir ./

Now edit the file "test.c" to say that the "test.h" file is to be found locally, rather than installed in a system location. The file should be changed to have the line:

#include "test.h"

Now compile the library:

$ gcc --shared -fPIC -o libtest.so $(pkg-config --cflags --libs gobject-2.0) test.c

Save the following code to a file called "hello.vala". This is the code that will use the library we have created.

using GLib;

public class Hello : GLib.Object {
    public static int main(string[] args) {
        MyLib test = new MyLib();

        test.hello();
        int x = 4, y = 5;
        stdout.printf("Sum: %d, %d\n", x, y);

        int result = test.sum(x, y);
        stdout.printf("Result: %d\n", result);

        return 0;
    }
}

Now compile the application code, telling the compiler that we want to link against the library we just created.

$ valac -X -I. -X -L. -X -ltest -o hello hello.vala test.vapi --basedir ./

We can now run the program. This command states that any required libraries will be found in the current directory.

$ LD_LIBRARY_PATH=$PWD ./hello

The output of the program should be:

Hello World, MyLib
Sum: 4, 5
Result: 9

Binding Libraries with VAPI Files

VAPI files are descriptions of the public interface of external Vala libraries. When a library is written in Vala, this file is created by the Vala compiler, and basically an amalgamation of all public (maybe internal also) definitions from all Vala source files. For a library written in C, the VAPI file gets more complicated, particular if the naming conventions of the library do not follow the GLib convention. The VAPI file will in this case contain many annotations describing how the standardised Vala interface mangles onto the C version.

This process of creating this generally amounts to 3 steps,

Running vala-gen-introspect to extract metadata from the C library.
Adding extra metadata to standardise the interface or make various other changes.
Generating a VAPI file from the above sources using vapigen.

Specific instructions on how to generate bindings are in the Vala Bindings Tutorial

Tools

The Vala distribution includes several programs to help you build and work with Vala applications. For more details of each tool, see the man pages.

valac

valac in the Vala compiler. It's primary function is to transform Vala code into compilable C code, though it can also automate the entire build and link project in simple cases.

The simple case for use is:

valac -o appname --pkg gee-1.0 file_name_1.vala file_name_2.vala

The o switch request that an object file is created, rather than just outputting C source files. The pkg option says that this build needs information from the "gee-1.0" package. You do no need to specify details about what libraries to link in, the package has this information internally. Finally, a list of source files is given. If you need a more complicated build process, omit the o switch, and continue the process manually, or through a script.

vala-gen-introspect

vala-gen-introspect is a tool for extracting metainformation about gobject based libraries. This can be used for creating VAPI files, and so binding the library for use in Vala programs. It is executed with the pkg-config name of a library

vapigen

vapigen creates a VAPI files from a library's metadata and any extra information required.

Techniques

Using GLib

GLib includes a large set of utilities, including wrappers for most of the standard libc functions and more. These tools are available on all Vala platforms, even those which are not POSIX compliant. For a complete description of all that GLib provides, see the GLib Reference Manual. That reference is related to the C API for GLib, but it is mainly very simple to work out how to translate into Vala.

The GLib functions are available in Vala through the following naming convention:

C API	Vala	Example
g_topic_foobar()	GLib.Topic.foobar()	GLib.Path.get_basename()

The GLib types can be used similarly:

Instantiate with	Call an object member with
GLib.Foo aFoo = new GLib.Foo();	aFoo.bar();

The APIs are not identical between C and Vala, but these naming rules should mean you can find the functions you need in the GLib VAPI files shipped with Vala, and from there find the parameters. This will hopefully suffice until more Vala documentation can be generated.

File Handling

For flexible file I/O and file handling see Vala/GIOSamples.

You can also use FileUtils.get_contents to load a file into a string.

string filename = "file.vala";
string content;
ulong len;
FileUtils.get_contents(filename, out content, out len);

Introductions to:

Gtk
GtkBuilder
Cairo
GStreamer?
Others?